cJSON/CMakeLists.txt

cmake_minimum_required(VERSION 2.8)

project(cJSON C)

set(CJSON_VERSION_MAJOR 1)
set(CJSON_VERSION_MINOR 0)
set(CJSON_VERSION_PATCH 0)
set(CJSON_VERSION_SO 1)
set(CJSON_UTILS_VERSION_SO 1)
set(CJSON_VERSION "${CJSON_VERSION_MAJOR}.${CJSON_VERSION_MINOR}.${CJSON_VERSION_PATCH}")

if(("${CMAKE_C_COMPILER_ID}" MATCHES "GNU") OR ("${CMAKE_C_COMPILER_ID}" MATCHES "Clang"))
    add_compile_options(-ansi -pedantic -Wall -Wextra -Werror -Wstrict-prototypes -Wwrite-strings)
endif()

#variables for pkg-config
set(prefix ${CMAKE_INSTALL_PREFIX})
set(libdir "${CMAKE_INSTALL_PREFIX}/lib")
set(version ${CJSON_VERSION})

option(BUILD_SHARED_LIBS "Build shared libraries" ON)

#cJSON
set(CJSON_LIB cjson)

file(GLOB HEADERS cJSON.h)
set(SOURCES cJSON.c)

add_library(${CJSON_LIB} ${HEADERS} ${SOURCES})
if (NOT WIN32)
    target_link_libraries(${CJSON_LIB} m)
endif()

configure_file("${CMAKE_CURRENT_SOURCE_DIR}/libcjson.pc.in"
    "${CMAKE_CURRENT_BINARY_DIR}/libcjson.pc" @ONLY)

install(TARGETS ${CJSON_LIB} DESTINATION lib${LIB_SUFFIX})
install(FILES cJSON.h DESTINATION include/cjson)
install (FILES ${CMAKE_CURRENT_BINARY_DIR}/libcjson.pc DESTINATION lib/pkgconfig)

set_target_properties(${CJSON_LIB}
    PROPERTIES
        SOVERSION ${CJSON_VERSION_SO}
        VERSION ${CJSON_VERSION})

#cJSON_Utils
option(ENABLE_CJSON_UTILS "Enable building the cJSON_Utils library." OFF)
if(ENABLE_CJSON_UTILS)
    set(CJSON_UTILS_LIB cjson_utils)

    file(GLOB HEADERS_UTILS cJSON_Utils.h)
    set(SOURCES_UTILS cJSON_Utils.c)

    add_library(${CJSON_UTILS_LIB} ${HEADERS_UTILS} ${SOURCES_UTILS})
    target_link_libraries(${CJSON_UTILS_LIB} ${CJSON_LIB})

    configure_file("${CMAKE_CURRENT_SOURCE_DIR}/libcjson_utils.pc.in"
        "${CMAKE_CURRENT_BINARY_DIR}/libcjson_utils.pc" @ONLY)

    install(TARGETS ${CJSON_UTILS_LIB} DESTINATION lib${LIB_SUFFIX})
    install(FILES cJSON_Utils.h DESTINATION include/cjson)
    install (FILES ${CMAKE_CURRENT_BINARY_DIR}/libcjson_utils.pc DESTINATION lib/pkgconfig)

    set_target_properties(${CJSON_UTILS_LIB}
        PROPERTIES
            SOVERSION ${CJSON_UTILS_VERSION_SO}
            VERSION ${CJSON_VERSION})
endif()

option(ENABLE_CJSON_TEST "Enable building cJSON test" ON)
if(ENABLE_CJSON_TEST)
    set(TEST_CJSON cJSON_test)
    add_executable(${TEST_CJSON} test.c)
    target_link_libraries(${TEST_CJSON} ${CJSON_LIB})

    if(ENABLE_CJSON_UTILS)
        set(TEST_CJSON_UTILS cJSON_test_utils)
        add_executable(${TEST_CJSON_UTILS} test_utils.c)
        target_link_libraries(${TEST_CJSON_UTILS} ${CJSON_UTILS_LIB})
    endif()
endif()